Ribbon Finance

1// SPDX-License-Identifier: MIT
2pragma solidity =0.8.4;
3
4import {SafeMath} from "@openzeppelin/contracts/utils/math/SafeMath.sol";
5import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
6import {
7    SafeERC20
8} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
9import {GnosisAuction} from "../../libraries/GnosisAuction.sol";
10import {Vault} from "../../libraries/Vault.sol";
11import {VaultLifecycle} from "../../libraries/VaultLifecycle.sol";
12import {VaultLifecycleSTETH} from "../../libraries/VaultLifecycleSTETH.sol";
13import {ShareMath} from "../../libraries/ShareMath.sol";
14import {RibbonVault} from "./base/RibbonVault.sol";
15import {
16    RibbonThetaSTETHVaultStorage
17} from "../../storage/RibbonThetaSTETHVaultStorage.sol";
18
19/**
20 * UPGRADEABILITY: Since we use the upgradeable proxy pattern, we must observe
21 * the inheritance chain closely.
22 * Any changes/appends in storage variable needs to happen in RibbonThetaSTETHVaultStorage.
23 * RibbonThetaSTETHVault should not inherit from any other contract aside from RibbonVault, RibbonThetaSTETHVaultStorage
24 */
25contract RibbonThetaSTETHVault is RibbonVault, RibbonThetaSTETHVaultStorage {
26    using SafeERC20 for IERC20;
27    using SafeMath for uint256;
28    using ShareMath for Vault.DepositReceipt;
29
30    /************************************************
31     *  IMMUTABLES & CONSTANTS
32     ***********************************************/
33
34    /// @notice is the factory contract used to spawn otokens. Used to lookup otokens.
35    address public immutable OTOKEN_FACTORY;
36
37    // The minimum duration for an option auction.
38    uint256 private constant MIN_AUCTION_DURATION = 5 minutes;
39
40    /************************************************
41     *  EVENTS
42     ***********************************************/
43
44    event OpenShort(
45        address indexed options,
46        uint256 depositAmount,
47        address indexed manager
48    );
49
50    event CloseShort(
51        address indexed options,
52        uint256 withdrawAmount,
53        address indexed manager
54    );
55
56    event NewOptionStrikeSelected(uint256 strikePrice, uint256 delta);
57
58    event PremiumDiscountSet(
59        uint256 premiumDiscount,
60        uint256 newPremiumDiscount
61    );
62
63    event AuctionDurationSet(
64        uint256 auctionDuration,
65        uint256 newAuctionDuration
66    );
67
68    event InstantWithdraw(
69        address indexed account,
70        uint256 amount,
71        uint256 round
72    );
73
74    event InitiateGnosisAuction(
75        address indexed auctioningToken,
76        address indexed biddingToken,
77        uint256 auctionCounter,
78        address indexed manager
79    );
80
81    /************************************************
82     *  CONSTRUCTOR & INITIALIZATION
83     ***********************************************/
84
85    /**
86     * @notice Initializes the contract with immutable variables
87     * @param _weth is the Wrapped Ether contract
88     * @param _usdc is the USDC contract
89     * @param _wsteth is the LDO contract
90     * @param _ldo is the LDO contract
91     * @param _oTokenFactory is the contract address for minting new opyn option types (strikes, asset, expiry)
92     * @param _gammaController is the contract address for opyn actions
93     * @param _marginPool is the contract address for providing collateral to opyn
94     * @param _gnosisEasyAuction is the contract address that facilitates gnosis auctions
95     * @param _crvPool is the steth/eth crv stables pool
96     */
97    constructor(
98        address _weth,
99        address _usdc,
100        address _wsteth,
101        address _ldo,
102        address _oTokenFactory,
103        address _gammaController,
104        address _marginPool,
105        address _gnosisEasyAuction,
106        address _crvPool
107    )
108        RibbonVault(
109            _weth,
110            _usdc,
111            _wsteth,
112            _ldo,
113            _gammaController,
114            _marginPool,
115            _gnosisEasyAuction,
116            _crvPool
117        )
118    {
119        require(_oTokenFactory != address(0), "!_oTokenFactory");
120        OTOKEN_FACTORY = _oTokenFactory;
121    }
122
123    /**
124     * @notice Initializes the OptionVault contract with storage variables.
125     * @param _owner is the owner of the vault with critical permissions
126     * @param _keeper is the keeper of the vault with medium permissions (weekly actions)
127     * @param _feeRecipient is the address to recieve vault performance and management fees
128     * @param _managementFee is the management fee pct.
129     * @param _performanceFee is the perfomance fee pct.
130     * @param _tokenName is the name of the token
131     * @param _tokenSymbol is the symbol of the token
132     * @param _optionsPremiumPricer is the address of the contract with the
133       black-scholes premium calculation logic
134     * @param _strikeSelection is the address of the contract with strike selection logic
135     * @param _premiumDiscount is the vault's discount applied to the premium
136     * @param _auctionDuration is the duration of the gnosis auction
137     * @param _vaultParams is the struct with vault general data
138     */
139    function initialize(
140        address _owner,
141        address _keeper,
142        address _feeRecipient,
143        uint256 _managementFee,
144        uint256 _performanceFee,
145        string memory _tokenName,
146        string memory _tokenSymbol,
147        address _optionsPremiumPricer,
148        address _strikeSelection,
149        uint32 _premiumDiscount,
150        uint256 _auctionDuration,
151        Vault.VaultParams calldata _vaultParams
152    ) external initializer {
153        baseInitialize(
154            _owner,
155            _keeper,
156            _feeRecipient,
157            _managementFee,
158            _performanceFee,
159            _tokenName,
160            _tokenSymbol,
161            _vaultParams
162        );
163        require(_optionsPremiumPricer != address(0), "!_optionsPremiumPricer");
164        require(_strikeSelection != address(0), "!_strikeSelection");
165        require(
166            _premiumDiscount > 0 &&
167                _premiumDiscount < 100 * Vault.PREMIUM_DISCOUNT_MULTIPLIER,
168            "!_premiumDiscount"
169        );
170        require(_auctionDuration >= MIN_AUCTION_DURATION, "!_auctionDuration");
171        optionsPremiumPricer = _optionsPremiumPricer;
172        strikeSelection = _strikeSelection;
173        premiumDiscount = _premiumDiscount;
174        auctionDuration = _auctionDuration;
175    }
176
177    /************************************************
178     *  SETTERS
179     ***********************************************/
180
181    /**
182     * @notice Sets the new discount on premiums for options we are selling
183     * @param newPremiumDiscount is the premium discount
184     */
185    function setPremiumDiscount(uint256 newPremiumDiscount) external onlyOwner {
186        require(
187            newPremiumDiscount > 0 &&
188                newPremiumDiscount < 100 * Vault.PREMIUM_DISCOUNT_MULTIPLIER,
189            "Invalid discount"
190        );
191
192        emit PremiumDiscountSet(premiumDiscount, newPremiumDiscount);
193        premiumDiscount = newPremiumDiscount;
194    }
195
196    /**
197     * @notice Sets the new auction duration
198     * @param newAuctionDuration is the auction duration
199     */
200    function setAuctionDuration(uint256 newAuctionDuration) external onlyOwner {
201        require(
202            newAuctionDuration >= MIN_AUCTION_DURATION,
203            "Invalid auction duration"
204        );
205        emit AuctionDurationSet(auctionDuration, newAuctionDuration);
206        auctionDuration = newAuctionDuration;
207    }
208
209    /**
210     * @notice Sets the new strike selection or options premium pricer contract
211     * @param newContract is the address of the new strike selection or options premium pricer contract
212     * @param isStrikeSelection is whether we are setting the strike selection contract
213     */
214    function setStrikeSelectionOrPricer(
215        address newContract,
216        bool isStrikeSelection
217    ) external onlyOwner {
218        require(newContract != address(0), "!newContract");
219        if (isStrikeSelection) {
220            strikeSelection = newContract;
221        } else {
222            optionsPremiumPricer = newContract;
223        }
224    }
225
226    /**
227     * @notice Optionality to set strike price manually
228     * @param strikePrice is the strike price of the new oTokens (decimals = 8)
229     */
230    function setStrikePrice(uint128 strikePrice)
231        external
232        onlyOwner
233        nonReentrant
234    {
235        require(strikePrice > 0, "!strikePrice");
236        overriddenStrikePrice = strikePrice;
237        lastStrikeOverrideRound = vaultState.round;
238    }
239
240    /************************************************
241     *  VAULT OPERATIONS
242     ***********************************************/
243
244    /**
245     * @notice Withdraws the assets on the vault using the outstanding `DepositReceipt.amount`
246     * @param amount is the amount to withdraw in `asset`
247     * @param minETHOut is the min amount of `asset` to recieve for the swapped amount of steth in crv pool
248     */
249    function withdrawInstantly(uint256 amount, uint256 minETHOut)
250        external
251        nonReentrant
252    {
253        Vault.DepositReceipt storage depositReceipt =
254            depositReceipts[msg.sender];
255
256        uint256 currentRound = vaultState.round;
257
258        require(amount > 0, "!amount");
259        require(depositReceipt.round == currentRound, "Invalid round");
260
261        uint256 receiptAmount = depositReceipt.amount;
262        require(receiptAmount >= amount, "Exceed amount");
263
264        // Subtraction underflow checks already ensure it is smaller than uint104
265        depositReceipt.amount = uint104(receiptAmount.sub(amount));
266        vaultState.totalPending = uint128(
267            uint256(vaultState.totalPending).sub(amount)
268        );

JavaScript Tests