Idex.io

1// SPDX-License-Identifier: LGPL-3.0-only
2​
3pragma solidity 0.6.8;
4pragma experimental ABIEncoderV2;
5​
6import { Address } from '@openzeppelin/contracts/utils/Address.sol';
7import {
8  SafeMath as SafeMath256
9} from '@openzeppelin/contracts/math/SafeMath.sol';
10​
11import { ICustodian } from './libraries/Interfaces.sol';
12import { Owned } from './Owned.sol';
13​
14​
15contract Governance is Owned {
16  using SafeMath256 for uint256;
17​
18  /**
19   * @notice Emitted when admin initiates upgrade of `Exchange` contract address on `Custodian` via
20   * `initiateExchangeUpgrade`
21   */
22  event ExchangeUpgradeInitiated(
23    address oldExchange,
24    address newExchange,
25    uint256 blockThreshold
26  );
27  /**
28   * @notice Emitted when admin cancels previously started `Exchange` upgrade with `cancelExchangeUpgrade`
29   */
30  event ExchangeUpgradeCanceled(address oldExchange, address newExchange);
31  /*
32   * @notice Emitted when admin finalizes `Exchange` upgrade via `finalizeExchangeUpgrade`
33   */
34  event ExchangeUpgradeFinalized(address oldExchange, address newExchange);
35  /*
36   * @notice Emitted when admin initiates upgrade of `Governance` contract address on `Custodian` via
37   * `initiateGovernanceUpgrade`
38   */
39  event GovernanceUpgradeInitiated(
40    address oldGovernance,
41    address newGovernance,
42    uint256 blockThreshold
43  );
44  /**
45   * @notice Emitted when admin cancels previously started `Governance` upgrade with `cancelGovernanceUpgrade`
46   */
47  event GovernanceUpgradeCanceled(address oldGovernance, address newGovernance);
48  /**
49   * @notice Emitted when admin finalizes `Governance` upgrade via `finalizeGovernanceUpgrade`, effectively replacing
50   * this contract and rendering it non-functioning
51   */
52  event GovernanceUpgradeFinalized(
53    address oldGovernance,
54    address newGovernance
55  );
56​
57  // Internally used structs //
58​
59  struct ContractUpgrade {
60    bool exists;
61    address newContract;
62    uint256 blockThreshold;
63  }
64​
65  // Storage //
66​
67  uint256 immutable _blockDelay;
68  ICustodian _custodian;
69  ContractUpgrade _currentExchangeUpgrade;
70  ContractUpgrade _currentGovernanceUpgrade;
71​
72  /**
73   * @notice Instantiate a new `Governance` contract
74   *
75   * @dev Sets `owner` and `admin` to `msg.sender`. Sets the values for `_blockDelay` governing `Exchange`
76   * and `Governance` upgrades. This value is immutable, and cannot be changed after construction
77   *
78   * @param blockDelay The minimum number of blocks that must be mined after initiating an `Exchange`
79   * or `Governance` upgrade before the upgrade may be finalized
80   */
81  constructor(uint256 blockDelay) public Owned() {
82    _blockDelay = blockDelay;
83  }
84​
85  /**
86   * @notice Sets the address of the `Custodian` contract. The `Custodian` accepts `Exchange` and
87   * `Governance` addresses in its constructor, after which they can only be changed by the
88   * `Governance` contract itself. Therefore the `Custodian` must be deployed last and its address
89   * set here on an existing `Governance` contract. This value is immutable once set and cannot be
90   * changed again
91   *
92   * @param newCustodian The address of the `Custodian` contract deployed against this `Governance`
93   * contract's address
94   */
95  function setCustodian(ICustodian newCustodian) external onlyAdmin {
96    require(_custodian == ICustodian(0x0), 'Custodian can only be set once');
97    require(Address.isContract(address(newCustodian)), 'Invalid address');
98​
99    _custodian = newCustodian;
100  }
101​
102  // Exchange upgrade //
103​
104  /**
105   * @notice Initiates `Exchange` contract upgrade proccess on `Custodian`. Once `blockDelay` has passed
106   * the process can be finalized with `finalizeExchangeUpgrade`
107   *
108   * @param newExchange The address of the new `Exchange` contract
109   */
110  function initiateExchangeUpgrade(address newExchange) external onlyAdmin {
111    require(Address.isContract(address(newExchange)), 'Invalid address');
112    require(
113      newExchange != _custodian.loadExchange(),
114      'Must be different from current Exchange'
115    );
116    require(
117      !_currentExchangeUpgrade.exists,
118      'Exchange upgrade already in progress'
119    );
120​
121    _currentExchangeUpgrade = ContractUpgrade(
122      true,
123      newExchange,
124      block.number.add(_blockDelay)
125    );
126​
127    emit ExchangeUpgradeInitiated(
128      _custodian.loadExchange(),
129      newExchange,
130      _currentExchangeUpgrade.blockThreshold
131    );
132  }
133​
134  /**
135   * @notice Cancels an in-flight `Exchange` contract upgrade that has not yet been finalized
136   */
137  function cancelExchangeUpgrade() external onlyAdmin {
138    require(_currentExchangeUpgrade.exists, 'No Exchange upgrade in progress');
139​
140    address newExchange = _currentExchangeUpgrade.newContract;
141    delete _currentExchangeUpgrade;
142​
143    emit ExchangeUpgradeCanceled(_custodian.loadExchange(), newExchange);
144  }
145​
146  /**
147   * @notice Finalizes the `Exchange` contract upgrade by changing the contract address on the `Custodian`
148   * contract with `setExchange`. The number of blocks specified by `_blockDelay` must have passed since calling
149   * `initiateExchangeUpgrade`
150   *
151   * @param newExchange The address of the new `Exchange` contract. Must equal the address provided to
152   * `initiateExchangeUpgrade`
153   */
154  function finalizeExchangeUpgrade(address newExchange) external onlyAdmin {
155    require(_currentExchangeUpgrade.exists, 'No Exchange upgrade in progress');
156    require(
157      _currentExchangeUpgrade.newContract == newExchange,
158      'Address mismatch'
159    );
160    require(
161      block.number >= _currentExchangeUpgrade.blockThreshold,
162      'Block threshold not yet reached'
163    );
164​
165    address oldExchange = _custodian.loadExchange();
166    _custodian.setExchange(newExchange);
167    delete _currentExchangeUpgrade;
168​
169    emit ExchangeUpgradeFinalized(oldExchange, newExchange);
170  }
171​
172  // Governance upgrade //
173​
174  /**
175   * @notice Initiates `Governance` contract upgrade proccess on `Custodian`. Once `blockDelay` has passed
176   * the process can be finalized with `finalizeGovernanceUpgrade`
177   *
178   * @param newGovernance The address of the new `Governan

Solidity Contracts

JavaScript Tests