Moonwell

1/**
2 * @title Moonwell's Comptroller Contract
3 * @author Moonwell
4 */
5contract Comptroller is ComptrollerVXStorage, ComptrollerInterface, ComptrollerErrorReporter, ExponentialNoError {
6    /// @notice Emitted when an admin supports a market
7    event MarketListed(MToken mToken);
8
9    /// @notice Emitted when an account enters a market
10    event MarketEntered(MToken mToken, address account);
11
12    /// @notice Emitted when an account exits a market
13    event MarketExited(MToken mToken, address account);
14
15    /// @notice Emitted when close factor is changed by admin
16    event NewCloseFactor(uint oldCloseFactorMantissa, uint newCloseFactorMantissa);
17
18    /// @notice Emitted when a collateral factor is changed by admin
19    event NewCollateralFactor(MToken mToken, uint oldCollateralFactorMantissa, uint newCollateralFactorMantissa);
20
21    /// @notice Emitted when liquidation incentive is changed by admin
22    event NewLiquidationIncentive(uint oldLiquidationIncentiveMantissa, uint newLiquidationIncentiveMantissa);
23
24    /// @notice Emitted when price oracle is changed
25    event NewPriceOracle(PriceOracle oldPriceOracle, PriceOracle newPriceOracle);
26
27    /// @notice Emitted when pause guardian is changed
28    event NewPauseGuardian(address oldPauseGuardian, address newPauseGuardian);
29
30    /// @notice Emitted when an action is paused globally
31    event ActionPaused(string action, bool pauseState);
32
33    /// @notice Emitted when an action is paused on a market
34    event ActionPaused(MToken mToken, string action, bool pauseState);
35
36    /// @notice Emitted when supply reward speed is updated
37    event SupplyRewardSpeedUpdated(uint8 rewardToken, MToken indexed mToken, uint newSupplyRewardSpeed);
38
39    /// @notice Emitted when borrow reward speed is updated
40    event BorrowRewardSpeedUpdated(uint8 rewardToken, MToken indexed mToken, uint newBorrowRewardSpeed);
41
42    /// @notice Emitted when a new WELL speed is set for a contributor
43    event ContributorWellSpeedUpdated(address indexed contributor, uint newSpeed);
44
45    /// @notice Emitted when WELL or GLMR is distributed to a borrower
46    event DistributedBorrowerReward(uint8 indexed tokenType, MToken indexed mToken, address indexed borrower, uint wellDelta, uint wellBorrowIndex);
47
48    /// @notice Emitted when WELL or GLMR is distributed to a supplier
49    event DistributedSupplierReward(uint8 indexed tokenType, MToken indexed mToken, address indexed supplier, uint wellDelta, uint wellSupplyIndex);
50
51    /// @notice Emitted when borrow cap for a mToken is changed
52    event NewBorrowCap(MToken indexed mToken, uint newBorrowCap);
53
54    /// @notice Emitted when borrow cap guardian is changed
55    event NewBorrowCapGuardian(address oldBorrowCapGuardian, address newBorrowCapGuardian);
56
57    /// @notice Emitted when WELL is granted by admin
58    event WellGranted(address recipient, uint amount);
59
60    /// @notice The initial WELL and GLMR index for a market
61    uint224 public constant initialIndexConstant = 1e36;
62
63    // closeFactorMantissa must be strictly greater than this value
64    uint internal constant closeFactorMinMantissa = 0.05e18; // 0.05
65
66    // closeFactorMantissa must not exceed this value
67    uint internal constant closeFactorMaxMantissa = 0.9e18; // 0.9
68
69    // No collateralFactorMantissa may exceed this value
70    uint internal constant collateralFactorMaxMantissa = 0.9e18; // 0.9
71
72    // reward token type to show WELL or GLMR
73    uint8 public constant rewardWell = 0;
74    uint8 public constant rewardGlmr = 1;
75
76    // The amount of gas to use when making a native asset transfer.
77    uint16 public gasAmount = 2300;
78
79    /// @notice Emitted when the admin changes the gas amount.
80    event NewGasAmount(uint16 oldGasAmount, uint16 newGasAmount);
81
82    constructor() public {
83        admin = msg.sender;
84    }
85
86    /*** Assets You Are In ***/
87
88    /**
89     * @notice Returns the assets an account has entered
90     * @param account The address of the account to pull assets for
91     * @return A dynamic list with the assets the account has entered
92     */
93    function getAssetsIn(address account) external view returns (MToken[] memory) {
94        MToken[] memory assetsIn = accountAssets[account];
95
96        return assetsIn;
97    }
98
99    /**
100     * @notice Returns whether the given account is entered in the given asset
101     * @param account The address of the account to check
102     * @param mToken The mToken to check
103     * @return True if the account is in the asset, otherwise false.
104     */
105    function checkMembership(address account, MToken mToken) external view returns (bool) {
106        return markets[address(mToken)].accountMembership[account];
107    }
108
109    /**
110     * @notice Add assets to be included in account liquidity calculation
111     * @param mTokens The list of addresses of the mToken markets to be enabled
112     * @return Success indicator for whether each corresponding market was entered
113     */
114    function enterMarkets(address[] memory mTokens) public returns (uint[] memory) {
115        uint len = mTokens.length;
116
117        uint[] memory results = new uint[](len);
118        for (uint i = 0; i < len; i++) {
119            MToken mToken = MToken(mTokens[i]);
120
121            results[i] = uint(addToMarketInternal(mToken, msg.sender));
122        }
123
124        return results;
125    }
126
127    /**
128     * @notice Add the market to the borrower's "assets in" for liquidity calculations
129     * @param mToken The market to enter
130     * @param borrower The address of the account to modify
131     * @return Success indicator for whether the market was entered
132     */
133    function addToMarketInternal(MToken mToken, address borrower) internal returns (Error) {
134        Market storage marketToJoin = markets[address(mToken)];
135
136        if (!marketToJoin.isListed) {
137            // market is not listed, cannot join
138            return Error.MARKET_NOT_LISTED;
139        }
140
141        if (marketToJoin.accountMembership[borrower] == true) {
142            // already joined
143            return Error.NO_ERROR;
144        }
145
146        // survived the gauntlet, add to list
147        // NOTE: we store these somewhat redundantly as a significant optimization
148        //  this avoids having to iterate through the list for the most common use cases
149        //  that is, only when we need to perform liquidity checks
150        //  and not whenever we want to check if an account is in a particular market
151        marketToJoin.accountMembership[borrower] = true;
152        accountAssets[borrower].push(mToken);
153
154        emit MarketEntered(mToken, borrower);
155
156        return Error.NO_ERROR;
157    }
158

JavaScript Tests