Opyn V2

1/* SPDX-License-Identifier: UNLICENSED */
2pragma solidity =0.6.10;
3
4import {ERC20Upgradeable} from "../packages/oz/upgradeability/ERC20Upgradeable.sol";
5import {ERC20PermitUpgradeable} from "../packages/oz/upgradeability/erc20-permit/ERC20PermitUpgradeable.sol";
6import {Strings} from "../packages/oz/Strings.sol";
7import {BokkyPooBahsDateTimeLibrary} from "../packages/BokkyPooBahsDateTimeLibrary.sol";
8import {AddressBookInterface} from "../interfaces/AddressBookInterface.sol";
9
10/**
11 * @title Otoken
12 * @author Opyn Team
13 * @notice Otoken is the ERC20 token for an option
14 * @dev The Otoken inherits ERC20Upgradeable because we need to use the init instead of constructor
15 */
16contract Otoken is ERC20PermitUpgradeable {
17    /// @notice address of the Controller module
18    address public controller;
19
20    /// @notice asset that the option references
21    address public underlyingAsset;
22
23    /// @notice asset that the strike price is denominated in
24    address public strikeAsset;
25
26    /// @notice asset that is held as collateral against short/written options
27    address public collateralAsset;
28
29    /// @notice strike price with decimals = 8
30    uint256 public strikePrice;
31
32    /// @notice expiration timestamp of the option, represented as a unix timestamp
33    uint256 public expiryTimestamp;
34
35    /// @notice True if a put option, False if a call option
36    bool public isPut;
37
38    uint256 private constant STRIKE_PRICE_SCALE = 1e8;
39    uint256 private constant STRIKE_PRICE_DIGITS = 8;
40
41    /**
42     * @notice initialize the oToken
43     * @param _addressBook addressbook module
44     * @param _underlyingAsset asset that the option references
45     * @param _strikeAsset asset that the strike price is denominated in
46     * @param _collateralAsset asset that is held as collateral against short/written options
47     * @param _strikePrice strike price with decimals = 8
48     * @param _expiryTimestamp expiration timestamp of the option, represented as a unix timestamp
49     * @param _isPut True if a put option, False if a call option
50     */
51    function init(
52        address _addressBook,
53        address _underlyingAsset,
54        address _strikeAsset,
55        address _collateralAsset,
56        uint256 _strikePrice,
57        uint256 _expiryTimestamp,
58        bool _isPut
59    ) external initializer {
60        controller = AddressBookInterface(_addressBook).getController();
61        underlyingAsset = _underlyingAsset;
62        strikeAsset = _strikeAsset;
63        collateralAsset = _collateralAsset;
64        strikePrice = _strikePrice;
65        expiryTimestamp = _expiryTimestamp;
66        isPut = _isPut;
67        (string memory tokenName, string memory tokenSymbol) = _getNameAndSymbol();
68        __ERC20_init_unchained(tokenName, tokenSymbol);
69        __ERC20Permit_init(tokenName);
70        _setupDecimals(8);
71    }
72
73    function getOtokenDetails()
74        external
75        view
76        returns (
77            address,
78            address,
79            address,
80            uint256,
81            uint256,
82            bool
83        )
84    {
85        return (collateralAsset, underlyingAsset, strikeAsset, strikePrice, expiryTimestamp, isPut);
86    }
87
88    /**
89     * @notice mint oToken for an account
90     * @dev Controller only method where access control is taken care of by _beforeTokenTransfer hook
91     * @param account account to mint token to
92     * @param amount amount to mint
93     */
94    function mintOtoken(address account, uint256 amount) external {
95        require(msg.sender == controller, "Otoken: Only Controller can mint Otokens");
96        _mint(account, amount);
97    }
98
99    /**
100     * @notice burn oToken from an account.
101     * @dev Controller only method where access control is taken care of by _beforeTokenTransfer hook
102     * @param account account to burn token from
103     * @param amount amount to burn
104     */
105    function burnOtoken(address account, uint256 amount) external {
106        require(msg.sender == controller, "Otoken: Only Controller can burn Otokens");
107        _burn(account, amount);
108    }
109
110    /**
111     * @notice generates the name and symbol for an option
112     * @dev this function uses a named return variable to avoid the stack-too-deep error
113     * @return tokenName (ex: ETHUSDC 05-September-2020 200 Put USDC Collateral)
114     * @return tokenSymbol (ex: oETHUSDC-05SEP20-200P)
115     */
116    function _getNameAndSymbol() internal view returns (string memory tokenName, string memory tokenSymbol) {
117        string memory underlying = ERC20Upgradeable(underlyingAsset).symbol();
118        string memory strike = ERC20Upgradeable(strikeAsset).symbol();
119        string memory collateral = ERC20Upgradeable(collateralAsset).symbol();
120        string memory displayStrikePrice = _getDisplayedStrikePrice(strikePrice);
121
122        // convert expiry to a readable string
123        (uint256 year, uint256 month, uint256 day) = BokkyPooBahsDateTimeLibrary.timestampToDate(expiryTimestamp);
124
125        // get option type string
126        (string memory typeSymbol, string memory typeFull) = _getOptionType(isPut);
127
128        //get option month string
129        (string memory monthSymbol, string memory monthFull) = _getMonth(month);
130
131        // concatenated name string: ETHUSDC 05-September-2020 200 Put USDC Collateral
132        tokenName = string(
133            abi.encodePacked(
134                underlying,
135                strike,
136                " ",
137                _uintTo2Chars(day),