Goldfinch

1// SPDX-License-Identifier: MIT
2
3pragma solidity 0.6.12;
4pragma experimental ABIEncoderV2;
5
6import "@openzeppelin/contracts-ethereum-package/contracts/math/SafeMath.sol";
7
8import "./BaseUpgradeablePausable.sol";
9import "./ConfigHelper.sol";
10import "../../interfaces/IGo.sol";
11import "../../interfaces/IUniqueIdentity0612.sol";
12
13contract Go is IGo, BaseUpgradeablePausable {
14  address public override uniqueIdentity;
15
16  using SafeMath for uint256;
17
18  GoldfinchConfig public config;
19  using ConfigHelper for GoldfinchConfig;
20
21  GoldfinchConfig public legacyGoList;
22  uint256[11] public allIdTypes;
23  event GoldfinchConfigUpdated(address indexed who, address configAddress);
24
25  function initialize(
26    address owner,
27    GoldfinchConfig _config,
28    address _uniqueIdentity
29  ) public initializer {
30    require(
31      owner != address(0) && address(_config) != address(0) && _uniqueIdentity != address(0),
32      "Owner and config and UniqueIdentity addresses cannot be empty"
33    );
34    __BaseUpgradeablePausable__init(owner);
35    _performUpgrade();
36    config = _config;
37    uniqueIdentity = _uniqueIdentity;
38  }
39
40  function updateGoldfinchConfig() external override onlyAdmin {
41    config = GoldfinchConfig(config.configAddress());
42    emit GoldfinchConfigUpdated(msg.sender, address(config));
43  }
44
45  function performUpgrade() external onlyAdmin {
46    return _performUpgrade();
47  }
48
49  function _performUpgrade() internal {
50    allIdTypes[0] = ID_TYPE_0;
51    allIdTypes[1] = ID_TYPE_1;
52    allIdTypes[2] = ID_TYPE_2;
53    allIdTypes[3] = ID_TYPE_3;
54    allIdTypes[4] = ID_TYPE_4;
55    allIdTypes[5] = ID_TYPE_5;
56    allIdTypes[6] = ID_TYPE_6;
57    allIdTypes[7] = ID_TYPE_7;
58    allIdTypes[8] = ID_TYPE_8;
59    allIdTypes[9] = ID_TYPE_9;
60    allIdTypes[10] = ID_TYPE_10;
61  }
62
63  /**
64   * @notice sets the config that will be used as the source of truth for the go
65   * list instead of the config currently associated. To use the associated config for to list, set the override
66   * to the null address.
67   */
68  function setLegacyGoList(GoldfinchConfig _legacyGoList) external onlyAdmin {
69    legacyGoList = _legacyGoList;
70  }
71
72  /**
73   * @notice Returns whether the provided account is go-listed for use of the Goldfinch protocol
74   * for any of the UID token types.
75   * This status is defined as: whether `balanceOf(account, id)` on the UniqueIdentity
76   * contract is non-zero (where `id` is a supported token id on UniqueIdentity), falling back to the
77   * account's status on the legacy go-list maintained on GoldfinchConfig.
78   * @param account The account whose go status to obtain
79   * @return The account's go status
80   */
81  function go(address account) public view override returns (bool) {
82    require(account != address(0), "Zero address is not go-listed");
83
84    if (_getLegacyGoList().goList(account) || IUniqueIdentity0612(uniqueIdentity).balanceOf(account, ID_TYPE_0) > 0) {
85      return true;
86    }
87
88    // start loop at index 1 because we checked index 0 above
89    for (uint256 i = 1; i < allIdTypes.length; ++i) {
90      uint256 idTypeBalance = IUniqueIdentity0612(uniqueIdentity).balanceOf(account, allIdTypes[i]);
91      if (idTypeBalance > 0) {
92        return true;
93      }
94    }
95    return false;
96  }
97
98  /**
99   * @notice Returns whether the provided account is go-listed for use of the Goldfinch protocol
100   * for defined UID token types
101   * @param account The account whose go status to obtain
102   * @param onlyIdTypes Array of id types to check balances
103   * @return The account's go status
104   */
105  function goOnlyIdTypes(address account, uint256[] memory onlyIdTypes) public view override returns (bool) {
106    require(account != address(0), "Zero address is not go-listed");
107    GoldfinchConfig goListSource = _getLegacyGoList();
108    for (uint256 i = 0; i < onlyIdTypes.length; ++i) {
109      if (onlyIdTypes[i] == ID_TYPE_0 && goListSource.goList(account)) {
110        return true;
111      }
112      uint256 idTypeBalance = IUniqueIdentity0612(uniqueIdentity).balanceOf(account, onlyIdTypes[i]);
113      if (idTypeBalance > 0) {
114        return true;
115      }
116    }
117    return false;
118  }
119
120  /**
121   * @notice Returns whether the provided account is go-listed for use of the SeniorPool on the Goldfinch protocol.
122   * @param account The account whose go status to obtain
123   * @return The account's go status
124   */
125  function goSeniorPool(address account) public view override returns (bool) {
126    require(account != address(0), "Zero address is not go-listed");
127    if (account == config.stakingRewardsAddress() || _getLegacyGoList().goList(account)) {
128      return true;
129    }
130    uint256[2] memory seniorPoolIdTypes = [ID_TYPE_0, ID_TYPE_1];
131    for (uint256 i = 0; i < seniorPoolIdTypes.length; ++i) {
132      uint256 idTypeBalance = IUniqueIdentity0612(uniqueIdentity).balanceOf(account, seniorPoolIdTypes[i]);
133      if (idTypeBalance > 0) {
134        return true;
135      }
136    }
137    return false;
138  }
139
140  function _getLegacyGoList() internal view returns (GoldfinchConfig) {
141    return address(legacyGoList) == address(0) ? config : legacyGoList;
142  }
143}

JavaScript Tests