0x Protocol

1/// @dev An extensible proxy contract that serves as a universal entry point for
2///      interacting with the 0x protocol.
3contract ZeroEx {
4    // solhint-disable separate-by-one-line-in-contract,indent,var-name-mixedcase
5    using LibBytesV06 for bytes;
6​
7    /// @dev Construct this contract and register the `BootstrapFeature` feature.
8    ///      After constructing this contract, `bootstrap()` should be called
9    ///      by `bootstrap()` to seed the initial feature set.
10    /// @param bootstrapper Who can call `bootstrap()`.
11    constructor(address bootstrapper) public {
12        // Temporarily create and register the bootstrap feature.
13        // It will deregister itself after `bootstrap()` has been called.
14        BootstrapFeature bootstrap = new BootstrapFeature(bootstrapper);
15        LibProxyStorage.getStorage().impls[bootstrap.bootstrap.selector] =
16            address(bootstrap);
17    }
18​
19    // solhint-disable state-visibility
20​
21    /// @dev Forwards calls to the appropriate implementation contract.
22    fallback() external payable {
23        bytes4 selector = msg.data.readBytes4(0);
24        address impl = getFunctionImplementation(selector);
25        if (impl == address(0)) {
26            _revertWithData(LibProxyRichErrors.NotImplementedError(selector));
27        }
28​
29        (bool success, bytes memory resultData) = impl.delegatecall(msg.data);
30        if (!success) {
31            _revertWithData(resultData);
32        }
33        _returnWithData(resultData);
34    }
35​
36    /// @dev Fallback for just receiving ether.
37    receive() external payable {}
38​
39    // solhint-enable state-visibility
40​
41    /// @dev Get the implementation contract of a registered function.
42    /// @param selector The function selector.
43    /// @return impl The implementation contract address.
44    function getFunctionImplementation(bytes4 selector)
45        public
46        view
47        returns (address impl)
48    {
49        return LibProxyStorage.getStorage().impls[selector];
50    }
51​
52    // @dev Revert with arbitrary bytes.
53    // @param data Revert data.
54    function _revertWithData(bytes memory data) private pure {
55        assembly { revert(add(data, 32), mload(data)) }
56    }
57​
58    // @dev Return with arbitrary bytes.
59    /// @param data Return data.
60    function _returnWithData(bytes memory data) private pure {
61        assembly { return(add(data, 32), mload(data)) }
62    }
63}

Solidity Contracts

JavaScript Tests